home *** CD-ROM | disk | FTP | other *** search
/ Turnbull China Bikeride / Turnbull China Bikeride - Disc 2.iso / STUTTGART / LANG / SCHEME / GNU / SCM4E1 / !Scm / slib / mwsynrul < prev    next >
Text File  |  1993-09-08  |  10KB  |  343 lines
  1. ; Copyright 1992 William Clinger
  2. ;
  3. ; Permission to copy this software, in whole or in part, to use this
  4. ; software for any lawful purpose, and to redistribute this software
  5. ; is granted subject to the restriction that all copies made of this
  6. ; software must include this copyright notice in full.
  7. ;
  8. ; I also request that you send me a copy of any improvements that you
  9. ; make to this software so that they may be incorporated within it to
  10. ; the benefit of the Scheme community.
  11.  
  12. ;;;; Compiler for a <transformer spec>.
  13.  
  14. ;;; The input is a <transformer spec> and a syntactic environment.
  15. ;;; Syntactic environments are described in another file.
  16.  
  17. ;;; Transormer specs are in slib.texi.
  18.  
  19. (define mw:pattern-variable-flag (list 'v))
  20. (define mw:ellipsis-pattern-flag (list 'e))
  21. (define mw:ellipsis-template-flag mw:ellipsis-pattern-flag)
  22.  
  23. (define (mw:make-patternvar v rank)
  24.   (vector mw:pattern-variable-flag v rank))
  25. (define (mw:make-ellipsis-pattern P vars)
  26.   (vector mw:ellipsis-pattern-flag P vars))
  27. (define (mw:make-ellipsis-template T vars)
  28.   (vector mw:ellipsis-template-flag T vars))
  29.  
  30. (define (mw:patternvar? x)
  31.   (and (vector? x)
  32.        (= (vector-length x) 3)
  33.        (eq? (vector-ref x 0) mw:pattern-variable-flag)))
  34.  
  35. (define (mw:ellipsis-pattern? x)
  36.   (and (vector? x)
  37.        (= (vector-length x) 3)
  38.        (eq? (vector-ref x 0) mw:ellipsis-pattern-flag)))
  39.  
  40. (define (mw:ellipsis-template? x)
  41.   (and (vector? x)
  42.        (= (vector-length x) 3)
  43.        (eq? (vector-ref x 0) mw:ellipsis-template-flag)))
  44.  
  45. (define (mw:patternvar-name V) (vector-ref V 1))
  46. (define (mw:patternvar-rank V) (vector-ref V 2))
  47. (define (mw:ellipsis-pattern P) (vector-ref P 1))
  48. (define (mw:ellipsis-pattern-vars P) (vector-ref P 2))
  49. (define (mw:ellipsis-template T) (vector-ref T 1))
  50. (define (mw:ellipsis-template-vars T) (vector-ref T 2))
  51.  
  52. (define (mw:pattern-variable v vars)
  53.   (cond ((null? vars) #f)
  54.     ((eq? v (mw:patternvar-name (car vars)))
  55.      (car vars))
  56.     (else (mw:pattern-variable v (cdr vars)))))
  57.  
  58. ; Given a <transformer spec> and a syntactic environment,
  59. ; returns a macro denotation.
  60. ;
  61. ; A macro denotation is of the form
  62. ;
  63. ;    (macro (<rule> ...) env)
  64. ;
  65. ; where each <rule> has been compiled as described above.
  66.  
  67. (define (mw:compile-transformer-spec spec env)
  68.   (if (and (> (mw:safe-length spec) 1)
  69.        (eq? (mw:syntax-lookup env (car spec))
  70.         mw:denote-of-syntax-rules))
  71.       (let ((literals (cadr spec))
  72.         (rules (cddr spec)))
  73.     (if (or (not (list? literals))
  74.         (not (comlist:every (lambda (rule)
  75.                   (and (= (mw:safe-length rule) 2)
  76.                    (pair? (car rule))))
  77.                   rules)))
  78.         (mw:error "Malformed syntax-rules" spec))
  79.     (list 'macro
  80.           (map (lambda (rule)
  81.              (mw:compile-rule rule literals env))
  82.            rules)
  83.           env))
  84.       (mw:error "Malformed syntax-rules" spec)))
  85.  
  86. (define (mw:compile-rule rule literals env)
  87.   (mw:compile-pattern (cdr (car rule))
  88.              literals
  89.              env
  90.              (lambda (compiled-rule patternvars)
  91.                ; should check uniqueness of pattern variables here!!!!!
  92.                (cons compiled-rule
  93.                  (mw:compile-template
  94.                   (cadr rule)
  95.                   patternvars
  96.                   env)))))
  97.  
  98. (define (mw:compile-pattern P literals env k)
  99.   (define (loop P vars rank k)
  100.     (cond ((symbol? P)
  101.        (if (memq P literals)
  102.            (k P vars)
  103.            (let ((var (mw:make-patternvar P rank)))
  104.          (k var (cons var vars)))))
  105.       ((null? P) (k '() vars))
  106.       ((pair? P)
  107.        (if (and (pair? (cdr P))
  108.             (symbol? (cadr P))
  109.             (eq? (mw:syntax-lookup env (cadr P))
  110.              mw:denote-of-...))
  111.            (if (null? (cddr P))
  112.            (loop (car P)
  113.              '()
  114.              (+ rank 1)
  115.              (lambda (P vars1)
  116.                (k (mw:make-ellipsis-pattern P vars1)
  117.                   (comlist:union vars1 vars))))
  118.            (mw:error "Malformed pattern" P))
  119.            (loop (car P)
  120.              vars
  121.              rank
  122.              (lambda (P1 vars)
  123.                (loop (cdr P)
  124.                  vars
  125.                  rank
  126.                  (lambda (P2 vars)
  127.                    (k (cons P1 P2) vars)))))))
  128.       ((vector? P)
  129.        (loop (vector->list P)
  130.          vars
  131.          rank
  132.          (lambda (P vars)
  133.            (k (vector P) vars))))
  134.       (else (k P vars))))
  135.   (loop P '() 0 k))
  136.  
  137. (define (mw:compile-template T vars env)
  138.   
  139.   (define (loop T inserted referenced rank escaped? k)
  140.     (cond ((symbol? T)
  141.        (let ((x (mw:pattern-variable T vars)))
  142.          (if x
  143.          (if (>= rank (mw:patternvar-rank x))
  144.              (k x inserted (cons x referenced))
  145.              (mw:error
  146.               "Too few ellipses follow pattern variable in template"
  147.               (mw:patternvar-name x)))
  148.          (k T (cons T inserted) referenced))))
  149.       ((null? T) (k '() inserted referenced))
  150.       ((pair? T)
  151.        (cond ((and (not escaped?)
  152.                (symbol? (car T))
  153.                (eq? (mw:syntax-lookup env (car T))
  154.                 mw:denote-of-:::)
  155.                (pair? (cdr T))
  156.                (null? (cddr T)))
  157.           (loop (cadr T) inserted referenced rank #t k))
  158.          ((and (not escaped?)
  159.                (pair? (cdr T))
  160.                (symbol? (cadr T))
  161.                (eq? (mw:syntax-lookup env (cadr T))
  162.                 mw:denote-of-...))
  163.           (loop1 T inserted referenced rank escaped? k))
  164.          (else
  165.           (loop (car T)
  166.             inserted
  167.             referenced
  168.             rank
  169.             escaped?
  170.             (lambda (T1 inserted referenced)
  171.               (loop (cdr T)
  172.                 inserted
  173.                 referenced
  174.                 rank
  175.                 escaped?
  176.                 (lambda (T2 inserted referenced)
  177.                   (k (cons T1 T2) inserted referenced))))))))
  178.       ((vector? T)
  179.        (loop (vector->list T)
  180.          inserted
  181.          referenced
  182.          rank
  183.          escaped?
  184.          (lambda (T inserted referenced)
  185.            (k (vector T) inserted referenced))))
  186.       (else (k T inserted referenced))))
  187.   
  188.   (define (loop1 T inserted referenced rank escaped? k)
  189.     (loop (car T)
  190.       inserted
  191.       '()
  192.       (+ rank 1)
  193.       escaped?
  194.       (lambda (T1 inserted referenced1)
  195.         (loop (cddr T)
  196.           inserted
  197.           (append referenced1 referenced)
  198.           rank
  199.           escaped?
  200.           (lambda (T2 inserted referenced)
  201.             (k (cons (mw:make-ellipsis-template
  202.                   T1
  203.                   (comlist:remove-if-not
  204.                    (lambda (var) (> (mw:patternvar-rank var)
  205.                         rank))
  206.                    referenced1))
  207.                  T2)
  208.                inserted
  209.                referenced))))))
  210.   
  211.   (loop T
  212.     '()
  213.     '()
  214.     0
  215.     #f
  216.     (lambda (T inserted referenced)
  217.       (list T inserted))))
  218.  
  219. ; The pattern matcher.
  220. ;
  221. ; Given an input, a pattern, and two syntactic environments,
  222. ; returns a pattern variable environment (represented as an alist)
  223. ; if the input matches the pattern, otherwise returns #f.
  224.  
  225. (define mw:empty-pattern-variable-environment
  226.   (list (mw:make-patternvar (string->symbol "") 0)))
  227.  
  228. (define (mw:match F P env-def env-use)
  229.   
  230.   (define (match F P answer rank)
  231.     (cond ((null? P)
  232.        (and (null? F) answer))
  233.       ((pair? P)
  234.        (and (pair? F)
  235.         (let ((answer (match (car F) (car P) answer rank)))
  236.           (and answer (match (cdr F) (cdr P) answer rank)))))
  237.       ((symbol? P)
  238.        (and (symbol? F)
  239.         (mw:same-denotation? (mw:syntax-lookup env-def P)
  240.                      (mw:syntax-lookup env-use F))
  241.         answer))
  242.       ((mw:patternvar? P)
  243.        (cons (cons P F) answer))
  244.       ((mw:ellipsis-pattern? P)
  245.        (match1 F P answer (+ rank 1)))
  246.       ((vector? P)
  247.        (and (vector? F)
  248.         (match (vector->list F) (vector-ref P 0) answer rank)))
  249.       (else (and (equal? F P) answer))))
  250.   
  251.   (define (match1 F P answer rank)
  252.     (cond ((not (list? F)) #f)
  253.       ((null? F)
  254.        (append (map (lambda (var) (cons var '()))
  255.             (mw:ellipsis-pattern-vars P))
  256.            answer))
  257.       (else
  258.        (let* ((P1 (mw:ellipsis-pattern P))
  259.           (answers (map (lambda (F) (match F P1 answer rank))
  260.                 F)))
  261.          (if (comlist:every comlist:identity answers)
  262.          (append (map (lambda (var)
  263.                 (cons var
  264.                       (map (lambda (answer)
  265.                          (cdr (assq var answer)))
  266.                        answers)))
  267.                   (mw:ellipsis-pattern-vars P))
  268.              answer)
  269.          #f)))))
  270.   
  271.   (match F P mw:empty-pattern-variable-environment 0))
  272.  
  273. (define (mw:rewrite T alist)
  274.   
  275.   (define (rewrite T alist rank)
  276.     (cond ((null? T) '())
  277.       ((pair? T)
  278.        ((if (mw:ellipsis-pattern? (car T))
  279.         append
  280.         cons)
  281.         (rewrite (car T) alist rank)
  282.         (rewrite (cdr T) alist rank)))
  283.       ((symbol? T) (cdr (assq T alist)))
  284.       ((mw:patternvar? T) (cdr (assq T alist)))
  285.       ((mw:ellipsis-template? T)
  286.        (rewrite1 T alist (+ rank 1)))
  287.       ((vector? T)
  288.        (list->vector (rewrite (vector-ref T 0) alist rank)))
  289.       (else T)))
  290.   
  291.   (define (rewrite1 T alist rank)
  292.     (let* ((T1 (mw:ellipsis-template T))
  293.        (vars (mw:ellipsis-template-vars T))
  294.        (rows (map (lambda (var) (cdr (assq var alist)))
  295.               vars)))
  296.       (map (lambda (alist) (rewrite T1 alist rank))
  297.        (make-columns vars rows alist))))
  298.   
  299.   (define (make-columns vars rows alist)
  300.     (define (loop rows)
  301.       (if (null? (car rows))
  302.       '()
  303.       (cons (append (map (lambda (var row)
  304.                    (cons var (car row)))
  305.                  vars
  306.                  rows)
  307.             alist)
  308.         (loop (map cdr rows)))))
  309.     (if (or (null? (cdr rows))
  310.         (apply = (map length rows)))
  311.     (loop rows)
  312.     (mw:error "Use of macro is not consistent with definition"
  313.          vars
  314.          rows)))
  315.   
  316.   (rewrite T alist 0))
  317.  
  318. ; Given a use of a macro, the syntactic environment of the use,
  319. ; and a continuation that expects a transcribed expression and
  320. ; a new environment in which to continue expansion,
  321. ; does the right thing.
  322.  
  323. (define (mw:transcribe exp env-use k)
  324.   (let* ((m (mw:syntax-lookup env-use (car exp)))
  325.      (rules (macwork:rules m))
  326.      (env-def (macwork:env m))
  327.      (F (cdr exp)))
  328.     (define (loop rules)
  329.       (if (null? rules)
  330.       (mw:error "Use of macro does not match definition" exp)
  331.       (let* ((rule (car rules))
  332.          (pattern (car rule))
  333.          (alist (mw:match F pattern env-def env-use)))
  334.         (if alist
  335.         (let* ((template (cadr rule))
  336.                (inserted (caddr rule))
  337.                (alist2 (mw:rename-vars inserted))
  338.                (newexp (mw:rewrite template (append alist2 alist))))
  339.           (k newexp
  340.              (mw:syntax-alias env-use alist2 env-def)))
  341.         (loop (cdr rules))))))
  342.     (loop rules)))
  343.